nixnew/modules/user/modules/firefox/default.nix

{ lib, pkgs, ... }@inputs:
let
  inherit (import ./prefgroups.nix inputs) modules prefgroups;

  extra-addons = let
    buildFirefoxXpiAddon = {
      src,
      pname,
      version,
      addonId
    }: pkgs.stdenv.mkDerivation {
      name = "${pname}-${version}";

      inherit src;

      preferLocalBuild = true;
      allowSubstitutes = true;

      buildCommand = ''
        dst="$out/share/mozilla/extensions/{ec8030f7-c20a-464f-9b0e-13a3a9e97384}"
        mkdir -p "$dst"
        install -v -m644 "$src" "$dst/${addonId}.xpi"
      '';
    };

    remoteXpiAddon = { pname, version, addonId, url, sha256 }: buildFirefoxXpiAddon {
      inherit pname version addonId;
      src = pkgs.fetchurl { inherit url sha256; };
    };

    theme = { name, theme }: buildFirefoxXpiAddon {
      pname = "firefox-theme-xpi-${name}";
      version = "1.0";
      addonId = "theme-${name}@outfoxxed.me";
      src = import ./theme.nix { inherit pkgs name theme; };
    };
  in {
    github-reposize = remoteXpiAddon {
      pname = "github-reposize";
      version = "1.7.0";
      addonId = "github-repo-size@mattelrah.com";
      url = "https://addons.mozilla.org/firefox/downloads/file/3854469/github_repo_size-1.7.0.xpi";
      sha256 = "2zGY12esYusaw2IzXM+1kP0B/0Urxu0yj7xXlDlutto=";
    };
    vencord = remoteXpiAddon {
      pname = "vencord";
      version = "1.2.7";
      addonId = "vencord-firefox@vendicated.dev";
      url = "https://addons.mozilla.org/firefox/downloads/file/4123132/vencord_web-1.2.7.xpi";
      sha256 = "A/XKdT0EuDHsQ7mcK9hsXAoAJYUt4Uvp/rtCf/9dAS0=";
    };

    theme-gray = theme {
      name = "theme-gray";
      theme.colors = {
        toolbar = "rgb(42, 46, 50)";
        toolbar_text = "rgb(255, 255, 255)";
        frame = "rgb(27, 30, 32)";
        tab_background_text = "rgb(215, 226, 239)";
        toolbar_field = "rgb(27, 30, 32)";
        toolbar_field_text = "rgb(255, 255, 255)";
        tab_line = "rgb(0, 0, 0)";
        popup = "rgb(42, 46, 50)";
        popup_text = "rgb(252, 252, 252)";
        tab_loading = "rgb(0, 0, 0)";
      };
    };

    theme-green = theme {
      name = "theme-green";
      theme.colors = {
        toolbar = "rgb(26, 53, 40)";
        toolbar_text = "rgb(255, 255, 255)";
        frame = "rgb(26, 43, 35)";
        tab_background_text = "rgb(215, 226, 239)";
        toolbar_field = "rgb(26, 43, 35)";
        toolbar_field_text = "rgb(255, 255, 255)";
        tab_line = "rgb(0, 0, 0)";
        popup = "rgb(42, 46, 50)";
        popup_text = "rgb(252, 252, 252)";
        tab_loading = "rgb(0, 0, 0)";
      };
    };

    theme-orange = theme {
      name = "theme-orange";
      theme.colors = {
        toolbar = "rgb(66, 44, 28)";
        toolbar_text = "rgb(255, 255, 255)";
        frame = "rgb(43, 34, 26)";
        tab_background_text = "rgb(215, 226, 239)";
        toolbar_field = "rgb(43, 34, 26)";
        toolbar_field_text = "rgb(255, 255, 255)";
        tab_line = "rgb(0, 0, 0)";
        popup = "rgb(42, 46, 50)";
        popup_text = "rgb(252, 252, 252)";
        tab_loading = "rgb(0, 0, 0)";
      };
    };

    theme-purple = theme {
      name = "theme-purple";
      theme.colors = {
        toolbar = "rgb(42, 28, 66)";
        toolbar_text = "rgb(255, 255, 255)";
        frame = "rgb(34, 26, 43)";
        tab_background_text = "rgb(215, 226, 239)";
        toolbar_field = "rgb(34, 26, 43)";
        toolbar_field_text = "rgb(255, 255, 255)";
        tab_line = "rgb(0, 0, 0)";
        popup = "rgb(42, 46, 50)";
        popup_text = "rgb(252, 252, 252)";
        tab_loading = "rgb(0, 0, 0)";
      };
    };
  };
in {
  programs.firefox = {
    enable = true;

    package = pkgs.firefox-devedition.overrideAttrs (pkg: let
      entries = {
        firefox-im = {
          name = "IMs (Firefox)";
          profile = "im";
          nomime = true;
          noremote = true;
        };

        firefox-trusted = {
          name = "Trusted Firefox";
          profile = "trusted";
          nomime = true;
        };

        firefox-work = {
          name = "Work Firefox";
          profile = "work";
          nomime = true;
        };

        firefox-general = {
          name = "Firefox";
          profile = "general";
        };

        firefox-schizo = {
          name = "Schizo Firefox";
          profile = "schizo";
          nomime = true;
        };
      };

      items = builtins.attrValues
        (builtins.mapAttrs (name: entry: pkg.desktopItem.override (item: {
          inherit name;
          desktopName = entry.name;

          mimeTypes = if entry ? nomime && entry.nomime
                      then []
                      else item.mimeTypes;

          actions = {};

          exec = "${item.exec} ${if entry ? noremote && entry.noremote then "-no-remote" else ""} -P ${entry.profile}";
        })) entries);
    in {
      buildCommand = ''
        ${pkg.buildCommand}
        rm $out/share/applications/*

        cat <<EOF > $out/share/applications/firefox.desktop
        [Desktop Entry]
        Version=1.4
        Type=Application
        Name=Firefox
        Icon=firefox-devedition
        NoDisplay=true
        EOF


      '' + lib.strings.concatMapStrings (item: "\ncp ${item}/share/applications/* $out/share/applications") items;
    });

    profiles = let
      mkProfile = { name, id, settings, extensions ? [] }: {
        inherit id settings name extensions;
        path = name;
        userChrome = ''
          ${builtins.readFile ./hide_drm_nagbar_chrome.css}
          ${builtins.readFile ./sideberry_chrome.css}
          ${builtins.readFile ./sideberry_hide_ext_button.css}
          ${builtins.readFile ./hide_content_borders.css}
        '';
      };
    in {
      base = {
        id = 10;
        name = "base";
      };

      schizo = mkProfile {
        id = 0;
        name = "schizo";
        settings = modules.schizo;

        extensions = with pkgs.nur.repos.rycee.firefox-addons; with extra-addons; [
          darkreader
          sidebery
          sponsorblock
          ublock-origin
          umatrix
          theme-purple
        ];
      };

      general = mkProfile {
        id = 1;
        name = "general";
        settings = modules.general;

        extensions = with pkgs.nur.repos.rycee.firefox-addons; with extra-addons; [
          keepassxc-browser
          darkreader
          github-reposize
          sidebery
          simplelogin
          sponsorblock
          ublock-origin
          umatrix
          theme-gray
        ];
      };

      im = {
        id = 2;
        name = "im";
        userChrome = builtins.readFile ./inline_tabs_chrome.css;
        settings = modules.base
        // prefgroups.misc.restore-pages;

        extensions = with pkgs.nur.repos.rycee.firefox-addons; with extra-addons; [
          ublock-origin
          vencord
        ];
      };

      trusted = mkProfile {
        id = 3;
        name = "trusted";
        settings = modules.trusted;

        extensions = with pkgs.nur.repos.rycee.firefox-addons; with extra-addons; [
          keepassxc-browser
          darkreader
          github-reposize
          sidebery
          simplelogin
          ublock-origin
          umatrix
          theme-green
        ];
      };

      work = mkProfile {
        id = 4;
        name = "work";
        settings = modules.trusted;

        extensions = with pkgs.nur.repos.rycee.firefox-addons; with extra-addons; [
          keepassxc-browser
          darkreader
          github-reposize
          sidebery
          simplelogin
          ublock-origin
          umatrix
          theme-orange
        ];
      };
    };
  };
}