{ self, lib, config, pkgs, ... }: {
  environment.systemPackages = with pkgs; [
    qt6.qtwayland
    kdePackages.breeze
    kdePackages.breeze-icons
    qt6.qtsvg # needed to load breeze icons

    # for testing kde things
    kdePackages.qqc2-desktop-style
    kdePackages.kirigami
    kdePackages.kirigami.unwrapped
    kdePackages.kirigami-addons
    kdePackages.sonnet
  ];

  qt = {
    enable = true;
    platformTheme = "qt5ct";
  };

  home-manager.users.${config.main-user} = {
    imports = [ ./home.nix ];
  };

  nixpkgs.overlays = [(final: prev: {
    qt6Packages = prev.qt6Packages.overrideScope (qfinal: qprev: {
      qt6ct = qprev.qt6ct.overrideAttrs (ctprev: {
        src = pkgs.fetchFromGitLab {
          domain = "www.opencode.net";
          owner = "ilya-fedin";
          repo = "qt6ct";
          rev = "6fa66ca94f1f8fa5119ad6669d5e3547f4077c1c"; # 'kde' branch
          sha256 = "z84z4XhAVqIJpF3m6H9FwFiDR7Nk+AY2tLpsibNEzPY=";
        };

        buildInputs = ctprev.buildInputs ++ (with final.kdePackages; [
          kconfig
          kcolorscheme
          kiconthemes
        ]);
      });
    });
  })];
}