Add devenv registry

modules/devenv/default.nix

@@ -0,0 +1,11 @@
+outerInputs @ { inputs, system, pkgs, ... }: {
+  nix.registry.devenv.flake.outPath = pkgs.runCommand "devenvs" {} ''
+    mkdir $out
+    cp -r ${./.}/* $out
+    cp ${inputs.self}/flake.lock $out/flake.lock
+  '';
+
+  system.extraDependencies = [
+    (import ./rust.nix outerInputs)
+  ];
+}

modules/devenv/flake.nix

@@ -0,0 +1,44 @@
+{
+  # locked by the copied lockfile. inputs must match the main flake
+  inputs = {
+    nixpkgs.url = "nixpkgs/nixos-unstable";
+    stable.url = "nixpkgs/nixos-23.05";
+
+    home-manager = {
+      url = "github:nix-community/home-manager";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+
+    hyprland = {
+      url = "github:hyprwm/Hyprland";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+
+    hyprland-hy3 = {
+      url = "github:outfoxxed/hy3";
+      inputs.hyprland.follows = "hyprland";
+    };
+
+    hyprpaper = {
+      url = "github:hyprwm/Hyprpaper";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+
+    # devenv
+    rust-overlay = {
+      url = "github:oxalica/rust-overlay";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+  };
+
+  outputs = finputs @ { nixpkgs, ... }: let
+    systems = [ "x86_64-linux" ];
+  in builtins.foldl' (a: b: a // b) {} (builtins.map (system: let
+      pkgs = import nixpkgs { inherit system; };
+      inputs = finputs // { inherit system pkgs inputs; };
+    in {
+      devShells.${system} = {
+        rust = import ./rust.nix inputs;
+      };
+    }) systems);
+}

modules/devenv/rust.nix

@@ -0,0 +1,28 @@
+outerInputs @ { inputs, ... }: let
+  pkgs = outerInputs.pkgs.appendOverlays [ (import inputs.rust-overlay) ];
+in pkgs.mkShell {
+  name = "rust-devenv";
+  packages = with pkgs; [
+    (rust-bin.selectLatestNightlyWith (toolchain: toolchain.default.override {
+      extensions = [
+        "rustc"
+        "rust-src"
+        "rust-docs"
+        "rust-std"
+        "cargo"
+        "clippy"
+        "rust-analyzer"
+        "miri"
+      ];
+    }))
+
+    cargo-expand
+
+    # common deps
+    clang
+    pkg-config
+    openssl.dev
+  ];
+
+  shellHook = "exec $SHELL";
+}